Закажите бесплатный расчет стоимости вашей задачи по 1С!
Перезвоним за 10 минут!

Запросы 1С 8 от А до Я

Что такое язык запросов

Язык запросов в 1С 8 это упрощенный аналог широкоизвестного «структурированного языка программирования» (как чаще его называют SQL). Но в 1С он используется только для чтения данных, для изменения данных используется объектная модель данных.

Еще одно интересное отличие языка запросов 1С – русский синтаксис. Хотя на самом деле Вы можете использовать и англоязычные конструкции.

Пример запроса:

ВЫБРАТЬ
Банки.Наименование,
Банки.КоррСчет
ИЗ
Справочник.Банки КАК Банки

Данный запрос позволит увидеть нам информацию о наименовании и корреспондентском счете всех существующих в базе данных банков.

Язык запросов – самой простой и эффективны способ получение информации. Как видно из примера выше, в языке запросов нужно апеллировать именами метаданных (метаданные в 1С 8.3 – это список объектов системы из которых состоит конфигурация, т.е справочники, документы, регистры и т.д.).

Описание конструкций языка запросов

Структура запросов

Для получения данных достаточно использовать конструкции «ВЫБРАТЬ» (select) и «ИЗ» (from). Простейший запрос выглядит следующим образом:

ВЫБРАТЬ * ИЗ Справочники.Номенклатура

Где «*» означает выбор всех полей таблицы, а Справочники.Номенклатура – имя таблицы в базе данных.

Рассмотрим, более сложный и общий пример:

ВЫБРАТЬ
<ИмяПоля1> КАК <ПредставлениеПоля1>,
Сумма(<ИмяПоля2>) КАК <ПредставлениеПоля2>
ИЗ
<ИмяТаблицы1> КАК <ПредставлениеТаблицы1>
<ТипСоединения> СОЕДИНЕНИЕ <ИмяТаблицы2> КАК <ПредставлениеТаблицы2>
ПО <УсловиеСоединениеТаблиц>

ГДЕ
<УсловиеОтбораДанных>

СГРУППИРОВАТЬ ПО
<ИмяПоля1>

УПОРЯДОЧИТЬ ПО
<ИмяПоля1>

ИТОГИ
<ИмяПоля2>
ПО
<ИмяПоля1>

В данном запросе мы выбираем данные полей «ИмяПоля1» и «ИмяПоля1» из таблиц «ИмяТаблицы1» и «ИмяТаблицы», присваиваем полям синонимы с помощью оператора «КАК» соединяем их по некому условию «УсловиеСоединениеТаблиц».

Из полученных данных мы отбираем только данные, соответствующие условию из «ГДЕ» «УсловиеОтбораДанных».Далее мы группируем запрос по полю «ИмяПоля1», при этом суммируя «ИмяПоля2».Создаём итоги по полю «ИмяПоля1» и итоговым полем «ИмяПоля2».

Последним действием мы сортируем запрос с помощью конструкции «УПОРЯДОЧИТЬ ПО». 

Общие конструкции

Рассмотрим общие конструкции языка запросов 1С 8.2.

ПЕРВЫЕ n

С помощью данного оператора можно получить n количество первых записей. Порядок записей определяется порядком в запросе.

Пример:

ВЫБРАТЬ ПЕРВЫЕ 100
Банки.Наименование,
Банки.Код КАК БИК
ИЗ
Справочник.Банки КАК Банки
УПОРЯДОЧИТЬ ПО
Банки.Наименование

Запросом будет получено первых 100 записей справочника «Банки», упорядоченных по алфавиту.

РАЗРЕШЕННЫЕ

Эта конструкция актуальна для работы с механизмом ограничений прав на уровне записей. Суть механизма в ограничении чтения (и других действий) пользователям для конкретных записей в таблице базы данных, а не таблицы в целом.

Если пользователь пытается с помощью запроса прочитать записи недоступные ему – он получит сообщение об ошибке. Что бы этого избежать – следует использовать конструкцию «РАЗРЕШЕННЫЕ», т.е запрос будет читать только разрешенные ему записи.

Пример:

ВЫБРАТЬ РАЗРЕШЕННЫЕ
ХранилищеДополнительнойИнформации.Ссылка
ИЗ
Справочник.ХранилищеДополнительнойИнформации

РАЗЛИЧНЫЕ

Использование «РАЗЛИЧНЫЕ» позволит исключить попадание строк-дублей в результат запроса 1С. Дублирование означает совпадение всех полей запроса.

Пример:

ВЫБРАТЬ ПЕРВЫЕ 100
Банки.Наименование,
Банки.Код КАК БИК
ИЗ
Справочник.Банки КАК Банки

ПустаяТаблица

Данная конструкция используется очень редко, для объединения запросов. При объединении может возникнуть необходимость указать в одной из таблиц пустую вложенную таблицу. Для этого как раз подойдет оператор «ПустаяТаблица»

Пример из справки 1С 8:

ВЫБРАТЬ Ссылка.Номер, ПУСТАЯТАБЛИЦА.(Ном, Тов, Кол) КАК Состав
ИЗ Документ.РасхНакл
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ Ссылка.Номер, Состав.(НомерСтроки, Товар, Количество)
ИЗ Документ.РасхНакл Документ.РасходнаяНакладная.Состав.*

ЕСТЬNULL

Очень полезная функция, которая позволяет избежать многих ошибок. ЕстьNULL() позволяет заменить значение NULL на нужное. Очень часто используется в проверках на наличие значения в присоединенных таблицах, например:

ВЫБРАТЬ
НоменклатураСпр.Ссылка,
ЕстьNULL(ОстаткиТовара.КоличествоОстаток,0) КАК КоличествоОстаток
ИЗ
Справочник.Номенклатура КАК НоменклатураСпр
ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.ТоварыНаСкладах.Остатки КАК ОстаткиТовара
ПО НоменклатураСпр.Ссылка = РеализованныеТоварыКомитентовОстатки.Номенклатура

Можно использовать и по другому. Например, если для каждой строки не известно, в какой таблице существует значение:

ЕСТЬNULL(СчетФактураПолученный.Дата, СчетФактураВыданный.Дата)

КАК

КАК – оператор, который позволяет нам присвоить имя (синоним) таблицы или полю. Пример использования мы видели выше.

ПРЕДСТАВЛЕНИЕ и ПРЕДСТАВЛЕНИЕССЫЛКИ

Данные конструкции очень похожи – они позволяют получить строковое представление нужного значения. Единственное отличие в том, что ПРЕДСТАВЛЕНИЕ преобразует любые значения в строковый тип, а ПРЕДСТАВЛЕНИЕССЫЛКИ только ссылочные. ПРЕДСТАВЛЕНИЕССЫЛКИ рекомендуется применять в запросах системы компоновки данных для оптимизации, если, конечно, поле ссылочных данных не планируется использовать в отборах отчета на СКД.

Пример:

ВЫБРАТЬ
Представление(Ссылка), //строка, например «Авансовый отчет №123 от 10.10.2015
Представление(ПометкаУдаления) КАК ПометкаУдаленияТекст, //строка, «Да» или «Нет»
ПредставлениеСсылки(ПометкаУдаления) КАК ПометкаУдаленияБулево  //булево, Истина или Ложь
ИЗ
Документ.АвансовыйОтчет

ВЫРАЗИТЬ

Выразить позволяет преобразовать значения поля к нужному типу данных. Можно преобразовать значение как к примитивному типу, так и к ссылочному типу.

«Выразить»для ссылочного типа используется для ограничения запрашиваемых типов данных в полях составного типа, часто используется для оптимизации работы системы. Пример:

ВЫРАЗИТЬ(ТаблицаЗатрат.Субконто1 КАК Справочник.СтатьиЗатрат).ВидДеятельностиДляНалоговогоУчетаЗатрат

Для примитивных типов эта функция часто используется для ограничения количества символов в полях неограниченной длинны (с такими полями нельзя сравнивать). Что бы избежать ошибки «Неверные параметры в операции сравнения. Нельзя сравнивать поля
неограниченной длины и поля несовместимых типов
» необходимо выразить такие поля следующим образом:

ВЫРАЗИТЬ(Комментарий КАК Строка(150))

РАЗНОСТЬДАТ

Оператор РазностьДат позволяет узнать разницу между двумя датами. В функции три параметра – (Первая дата, Вторая дата, Тип получаемого результата). Тип результата может принимать значения – Секунда,Минута, Час, День, Декада, Месяц, Квартал, Полугодие, Год.

Пример:

РАЗНОСТЬДАТ(ДАТАВРЕМЯ(1962, 04, 16, 00, 00, 00), ДАТАВРЕМЯ(2014, 06, 01, 00, 00, 00), ДЕНЬ) // получим 19039 дней
РАЗНОСТЬДАТ(ДАТАВРЕМЯ(1962, 04, 16, 00, 00, 00), ДАТАВРЕМЯ(2014, 06, 01, 00, 00, 00), ДЕНЬ) // или 626 месяцев

ДОБАВИТЬКДАТЕ

ДОБАВИТЬКДАТЕ Позволяет прибавлять или вычитать время из указанного выражения. Синтаксис – (Дата, Тип вычитания/прибавления, Количество). Тип вычитания/прибавления — Секунда, Минута, Час, День, Декада, Месяц, Квартал, Полугодие, Год. Если из даты необходимо вычесть используется «Количество» с минусом

Например:

ДОБАВИТЬКДАТЕ(ДАТАВРЕМЯ(1962, 04, 16, 00, 00, 00), Месяц, -1) // получим 16.03.1962 0:00:00
ДОБАВИТЬКДАТЕ(ДАТАВРЕМЯ(1962, 04, 16, 00, 00, 00), Квартал, 3) // 16.01.1963 0:00:00

НАЧАЛОПЕРИОДА … КОНЕЦПЕРИОДА

С помощью этих функции можно получить конец или начало периода по указанному типу. Параметры – (Дата, Тип периода). Тип периода -Минута, Час, День, Декада, Месяц, Квартал, Полугодие, Год.

Пример:

НачалоПериода(ДАТАВРЕМЯ(1962, 04, 16, 22, 33, 00), День), // получим начало дня

НачалоПериода(ДАТАВРЕМЯ(1962, 04, 16, 22, 33, 00), Год), // 01.01.1962

СЕКУНДА … ГОД

С помощью этих операторов можно получить временное значение конкретного типа из поля типа «Дата». Возвращаемое значение имеет тип «Число». Бывают функции: Секунда, Минута, Час, День, ДеньНедели, ДеньГода, Декада, Месяц, Квартал, Полугодие, Год.

Например:

Год(ДАТАВРЕМЯ(1962, 04, 16, 00, 00, 00)), //1962
ДеньГода(ДАТАВРЕМЯ(1962, 04, 16, 00, 00, 00)), // 106

ПОДСТРОКА

Аналог функции Сред() из объектной модели. Она позволяет выделить подстроку из исходной строки. Синтаксис – (Исходная строка, Позиция символа с которого начинается выделение, Сколько символов выделяется). Если длина строки меньше, чем указана во втором параметра, то функция вернет пустую строку.

Пример использования функции ПОДСТРОКА в запросе 1С:

ПОДСТРОКА(«Лопата»,2,3) // «лопата» превращается в «опа»

ВЫБОР КОГДА … ИНАЧЕ … КОНЕЦ

Очень полезная функция, которая позволяет прописать прямо в запросе условия. Функция часто может помочь когда необходимо в запросе менять значения поля в зависимости от других полей.

Пример:

ВЫБРАТЬ
ВЫБОР
КОГДА Номенклатура.Услуга
ТОГДА «Это услуга, Выписывайте акт!»
КОГДА НЕ Номенклатура.Услуга
ТОГДА «Это товар, подойдет накладная!»
ИНАЧЕ «Не ясно что это, да и такой вариант маловероятен 🙂 »
КОНЕЦ КАК Комментарий
ИЗ
Справочник.Номенклатура 

Отборы

Как правило, из всех полученных данных в запросе нам необходимо меньше 1% информации. Что бы не обрабатывать все записи, на условие запроса необходимо установить отборы только по нужным нам условиям.

В языке запросов 1С 8 используется следующие ограничения для получаемых данных:

Конструкция «ГДЕ»

В обычном случае для отборов используется конструкция «ГДЕ». Например:

ВЫБРАТЬ * ИЗ Справочник.Номенклатура ГДЕ (Наименование = «Лопата» И Услуга = Истина)

После «где» необходимо установить задать логическое условие, по которому необходимо отобрать строки.

Если говорить грубо, программа обходит все строки таблицы и сравнивает их с условием. Если для строки логическое выражение после «ГДЕ» равно Истина, то такая запись нам подходит и мы выведем её в результате запроса 1С.

«ГДЕ» не следует использовать для виртуальных таблицы запроса. Это грубейшая ошибка с точки зрения оптимизации. Для них используются специальные отборы виртуальных таблиц.

Отборы в виртуальных таблицах

Для оптимизации скорости и правильной работы виртуальных таблиц, в запросах с виртуальными таблицами следует использовать специализированные отборы.

В конструкторе запросов их можно вызвав контекстное меню с помощью нажатия правой клавиши мыши на нужную таблицу:

указание параметров виртуальной таблицы

В тексте запроса это выглядит так:

ВЫБРАТЬ
ВзаиморасчетыССотрудникамиОстатки.Сотрудник,
ВзаиморасчетыССотрудникамиОстатки.СуммаВзаиморасчетовОстаток
ИЗ
РегистрНакопления.ВзаиморасчетыССотрудниками.Остатки(
&Дата,
Организация = &Организация И Сотрудник В (&СписокСотрудников)) КАК ВзаиморасчетыССотрудникамиОстатки

ИМЕЮЩИЕ

Конструкция, о которой часто забывают, но она очень важна и полезна. Она позволяет указать отбор в виде агрегатной функции, этого нельзя сделать в конструкции ГДЕ.

Например:

ВЫБРАТЬ
ПоступлениеТоваровУслугТовары.Товар,
СУММА(ПоступлениеТоваровУслугТовары.Количество) КАК Количество,
СУММА(ПоступлениеТоваровУслугТовары.Сумма) КАК Сумма
ИЗ
Документ.ПоступлениеТоваровУслуг.Товары КАК ПоступлениеТоваровУслугТовары
СГРУППИРОВАТЬ ПО
ПоступлениеТоваровУслугТовары.товар
ИМЕЮЩИЕ
СУММА(ПоступлениеТоваровУслугТовары.Количество) > 5

Так мы отберем количество товаров, которых поступило более 5 штук.

Логические выражения

Логическое выражение – операция над произвольными выражениями, которая возвращает значение типа булево (ИСТИНА или ЛОЖЬ). Внутри операции можно использовать выражения И, ИЛИ, НЕ. С помощью логических операций в языке запросов 1С устанавливаются отборы, условия соединений и т.д.

Пример:

ВЫБРАТЬ
НоменклатураСпр.Ссылка,
ЕстьNULL(ОстаткиТовара.КоличествоОстаток,0) КАК КоличествоОстаток
ИЗ
Справочник.Номенклатура КАК НоменклатураСпр
ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.ТоварыНаСкладах.Остатки КАК ОстаткиТовара
ПО (НоменклатураСпр.Ссылка = РеализованныеТоварыКомитентовОстатки.Номенклатура)
ГДЕ
(НоменклатураСпр.Услуга = Истина И ОстаткиТовара.КоличествоОстаток > 10)

В данном запросе логические операции подчеркнуты.

= > < <>

Это классические математические операции сравнения: равно, больше, меньше. Символы «<>» означают НЕ равно, его также можно заменить на приставку «НЕ».

Пример:

Выражение

ГДЕ
(НоменклатураСпр.Услуга <> Истина И И ОстаткиТовара.КоличествоОстаток > 10)

Аналогично:

ГДЕ
(НЕ НоменклатураСпр.Услуга = Истина И И ОстаткиТовара.КоличествоОстаток > 10)

В, В ИЕРАРХИИ

Конструкция «В» позволяет сравнить значения поля с произвольным списком значения, массива или другого запроса. Если поле присутствует в указанном списке – выражение вернет ИСТИНА. Примеры:

НоменклатураСпр.Наименование В («Лопата», «Грабли», «Совок»)

НоменклатураСпр.Наименование В (ВЫБРАТЬ ВТ.Наименование ИЗ ВТ)

НоменклатураСпр.Наименование В (&СписокНаименований)

«В ИЕРАРХИИ» конструкция, которой нет аналогов в обычном языке SQL. Она проверяет принадлежность значения к вложенной иерархии.

Пример:

НоменклатураСпр.Ссылка В (&Группа)

            МЕЖДУ

Оператор «МЕЖДУ» позволяет определить вхождение значения в какой то интервал.

Пример:

НоменклатураСпр.ЦенаНоменклатуры МЕЖДУ 10 И 100

Такое условие отберет нам номенклатуру с ценой от 10 до 100.

            ПОДОБНО

Подобно – аналог LIKE из языка запросов SQL. С помощью «ПОДОБНО» можно сравнить строковые значения по частичному вхождению или маске.

Служебные символы для шаблонов:

  • % (процент): любое количество произвольных символов.
    Пример: ГДЕ Номенклатура.Наименование ПОДОБНО «Радио%» — отберет всю номенклатуру, наименование которой начинается на «Радио…»;
  • _ (подчеркивание): один произвольный символ
    Пример: ГДЕ Номенклатура.Наименование ПОДОБНО «_ок» — под такое условие подойдут наименование номенклатуры, такие как: «кок», «бок», «док» и т.п.;
  • […] (в квадратных скобках один или несколько символов): любой одиночный символ из перечисленных внутри квадратных скобок. Можно задать значение в виде диапазона [а-г] или перечисления [абвг].
    Пример: ГДЕ Номенклатура.Наименование ПОДОБНО «[а-д]ок» — под такое условие подойдут «док», «бок», но не подойдет «кок»;
  • [^…] это аналог предыдущего способа, только указанные в скобках символы НЕ будут включены в условие.
    Пример: ГДЕ Номенклатура.Наименование ПОДОБНО «[а-д]ок» — под такое условие НЕ подойдут «док», «бок», зато подойдет «кок»;

            ЕСТЬ NULL

Оператор ЕСТЬ NULL (или IS NULL) сравнивает значение с типом NULL. В языке запросов нельзя использовать сравнение вида «Поле = NULL», так как подобная конструкция будет работать в разных СУБД по-разному. Связано это с не типизированным значением NULL в различных СУБД (особенности работы разных СУБД для 1С).

Получите 267 видеоуроков по 1С бесплатно:

Пример использования ЕСТЬ NULL в запросе 1С:

ВЫБРАТЬ * ИЗ
Справочник.Номенклатура КАК НоменклатураСпр
ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.ТоварыНаСкладах.Остатки КАК ОстаткиТовара
ПО НоменклатураСпр.Ссылка = РеализованныеТоварыКомитентовОстатки.Номенклатура
ГДЕ НЕ ОстаткиТовара.КоличествоОстаток ЕСТЬ NULL

ТИПЗНАЧЕНИЯ, ТИП, ССЫЛКА

Тип данных в запросе можно определить следующим образом с помощью функций ТИП() и ТИПЗНАЧЕНИЯ() или с помощью логический оператора ССЫЛКА. Эти две функции аналогичны.

Пример:

ГДЕ ТИПЗНАЧЕНИЯ(Проект.Ссылка) <> ТИП(Справочник.Проект)

или

ГДЕ Проект.Ссылка ССЫЛКА Справочник.Проект

Предопределенные значения

Помимо использования в запросах переданных параметров в языке запросов 1С можно использовать предопределенные значения или пустые ссылки. Например, перечисления, предопределенные справочники, планы счетов и так далее.Для этого используется конструкция «Значение()».

Пример использования:

ГДЕ Номенклатура.ВидНоменклатуры = Значение(Справочник.ВидыНоменклатуры.Товар)

или

ГДЕ Контрагенты.ВидКонтактнойИнформации = Значение(Перечисление.ВидыКонтактнойИнформации.Телефон)

или

ГДЕ ОстаткиПоСчетам.СчетУчета = Значение(ПланСчетов.Хозрасчетный.ПрибылиУбытки)

Соединения

Соединения бывают 4 типов: ЛЕВОЕПРАВОЕПОЛНОЕ, ВНУТРЕННЕЕ.

ЛЕВОЕ и ПРАВОЕ СОЕДИНЕНИЕ

Соединения используются для связи двух таблиц по определенному условию. Особенность при ЛЕВОМ СОЕДИНЕНИИ в том, что мы берём первую указанную таблицу полностью и привязываем по условию вторую таблицу. Поля второй таблицы, которые не удалось привязать по условию, заполняются значением NULL.

Например:

ВЫБРАТЬ
Клиенты.Ссылка КАК Контрагент,
Банки.Ссылка КАК Банк
ИЗ
Справочник.Контрагенты КАК Клиенты
ЛЕВОЕ СОЕДИНЕНИЕ
Справочник.Банки КАК Банки
ПО
Клиенты.Наименование = Банки.Наименование

Вернет всю таблицу Контрагентов и заполнит поле “Банк”, лишь в тех местах, где будет соблюдаться условие “Контрагенты.Наименование = Банки.Наименование”. Если условие не соблюдается, в поле Банк будет установлено NULL.

ПРАВОЕ СОЕДИНЕНИЕ, в языке 1С, абсолютно аналогично ЛЕВОМУ соединению, за исключением одного отличия – в ПРАВОМ СОЕДИНЕНИИ “главная” таблица – вторая, а не первая.

ПОЛНОЕ СОЕДИНЕНИЕ

ПОЛНОЕ СОЕДИНЕНИЕ отличается от левого и правого тем, выводит все записи из двух таблиц, соединяет лишь те, которые может соединить по условию.

Например:

ВЫБРАТЬ
Клиенты.Ссылка КАК Клиенты,
Банки.Ссылка КАК Банк

ИЗ
Справочник.Контрагенты КАК Клиенты

ПОЛНОЕ СОЕДИНЕНИЕ
Справочник.Банки КАК Банки

ПО
Клиенты.Наименование = Банки.Наименование

Язык запросов вернет обе таблицы полностью, лишь по выполненному условию соединить записи. В отличие от левого/правого соединения возможно появления NULL в двух полях.

ВНУТРЕННЕЕ СОЕДИНЕНИЕ

ВНУТРЕННЕЕ СОЕДИНЕНИЕ отличается от полного тем, что выводит только те записи, которые смогли соединить по заданному условию.

Например:

ВЫБРАТЬ
Клиенты.Ссылка КАК Клиенты,
Банки.Ссылка КАК Банк

ИЗ
Справочник.Контрагенты КАК Клиенты

ВНУТРЕННЕЕ СОЕДИНЕНИЕ
Справочник.Банки КАК Банки

ПО
Клиенты.Наименование = Банки.Наименование

Данный запрос вернет только строки, в которых у банка и контрагента будет одинаковое наименование.

Объединения

Конструкция ОБЪЕДИНИТЬ и ОБЪЕДИНИТЬ ВСЕ объединяет два результата запроса в один. Т.е. результат выполнения двух запросов будет «слит» в один, общий.

Пример запроса для вывода всех документов поступлений и реализации:

ВЫБРАТЬ
РеализацияТоваровУслуг.Ссылка
ИЗ
Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
ОБЪЕДИНИТЬ ВСЕ
ВЫБРАТЬ
ПоступлениеТоваровУслуг.Ссылка
ИЗ
Документ.ПоступлениеТоваровУслуг КАК ПоступлениеТоваровУслуг

Запрос получит данные из двух таблиц и объединит их.

ОБЪЕДИНИТЬ часто используется для оптимизации запросов, что бы заменить оператор «ИЛИ» в условии запроса на несколько объединенных запросов (подробнее в главе «Оптимизация запросов»).

Разница между ОБЪЕДИНИТЬ и ОБЪЕДИНИТЬ ВСЕ

Конструкция ОБЪЕДИНИТЬ соединяет два результата и группирует повторяющие строки, в отличии от ОБЪЕДИНИТЬ ВСЕ которая не группирует автоматически строки результата.

Настоятельно рекомендуется использовать ОБЪЕДИНИТЬ ВСЕ в запросах, где заведомо невозможно получения одинаковых строк. Это существенно повышает производительность – система не пытается группировать строки.

Индексация полей запросов

Индексация в запросе нужна для ускорения формирования результате запроса. Как это работает? Система строит индекс для временной таблицы, что бы быстрее найти нужное значение (подробнее – индексы в 1С).

Т.е система работает точно также, как и обычные индексы 1С, только для временной таблицы.

Как использовать ИНДЕКСИРОВАТЬ ПО

Конструкцию рекомендуется использовать по полям временных таблиц, по которым эта временная таблица будет соединяться с другими таблицами баз данных. Это существенно повышает скорость выполнения соединения таблиц.

Однако, следует учесть один момент. Построение индекса временной таблицы так же требует времени на выполнение. Поэтому целесообразно использовать конструкцию ”ИНДЕКСИРОВАТЬ ПО”, только если точно известно, что во временной таблице будет не 1-2 записи. В противном случае эффект может быть обратным – быстродействие от индексированных полей не компенсирует времени построения индекса.

Пример:

ВЫБРАТЬ
КурсыВалютСрезПоследних.Валюта КАК Валюта,
КурсыВалютСрезПоследних.Курс
ПОМЕСТИТЬ КурсыВалют
ИЗ
РегистрСведений.КурсыВалют.СрезПоследних(&Период, ) КАК КурсыВалютСрезПоследних
ИНДЕКСИРОВАТЬ ПО
Валюта
;
////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
ЦеныНоменклатуры.Номенклатура,
ЦеныНоменклатуры.Цена,
ЦеныНоменклатуры.Валюта,
КурсыВалют.Курс
ИЗ
РегистрСведений.ЦеныНоменклатуры.СрезПоследних(&Период,
Номенклатура В (&Номенклатура) И ТипЦен = &ТипЦен) КАК ЦеныНоменклатуры
ЛЕВОЕ СОЕДИНЕНИЕ КурсыВалют КАК КурсыВалют
ПО ЦеныНоменклатуры.Валюта = КурсыВалют.Валюта

Группировка

Язык запросов 1С позволяет использовать специальные агрегатные функции при группировке результате запросов. Группировку можно также использовать без агрегатных функций, для «устранения» дублей.




Существуют следующие функции:

Сумма, Количество, Количество разных, Максимум, Минимум, Среднее.

Пример №1:

ВЫБРАТЬ
РеализацияТоваровУслугТовары.Номенклатура,
СУММА(РеализацияТоваровУслугТовары.Количество) КАК Количество,
СУММА(РеализацияТоваровУслугТовары.Сумма) КАК Сумма
ИЗ
Документ.РеализацияТоваровУслуг.Товары КАК РеализацияТоваровУслугТовары
СГРУППИРОВАТЬ ПО
РеализацияТоваровУслугТовары.Номенклатура

Запрос получает все строки с товарами и суммирует их по количеству и суммам в разрезе номенклатуры.

Пример №2

ВЫБРАТЬ
Банки.Код,
КОЛИЧЕСТВО(РАЗЛИЧНЫЕ Банки.Ссылка) КАК КоличествоДублей
ИЗ
Справочник.Банки КАК Банки
СГРУППИРОВАТЬ ПО
Банки.Код

Данный пример отобразит список БИКов справочника «Банки» и покажет сколько дублей существует по каждому из них.

Итоги

Итоги – способ получения данных из системы с иерархической структурой. Для итоговых полей могут использоваться агрегатные функции, как для группировок.

Один из самых популярных способов использования итогов в практике – партионное списания товаров.

Пример:

ВЫБРАТЬ
РеализацияТоваровУслугТовары.Номенклатура КАК Номенклатура,
РеализацияТоваровУслугТовары.Ссылка КАК Документ,
РеализацияТоваровУслугТовары.Количество КАК Количество,
РеализацияТоваровУслугТовары.Сумма КАК Сумма
ИЗ
Документ.РеализацияТоваровУслуг.Товары КАК РеализацияТоваровУслугТовары
УПОРЯДОЧИТЬ ПО
РеализацияТоваровУслугТовары.Ссылка.Дата
ИТОГИ
СУММА(Количество),
СУММА(Сумма)
ПО
Номенклатура

В результате запроса получится следующее иерархическое дерево значений:

дерево значений

Общие итоги

Если необходимо получить итоги по всем «итогам» используйте оператор «ОБЩИЕ».

Пример:

ВЫБРАТЬ
РеализацияТоваровУслугТовары.Номенклатура КАК Номенклатура,
РеализацияТоваровУслугТовары.Ссылка КАК Документ,
РеализацияТоваровУслугТовары.Количество КАК Количество,
РеализацияТоваровУслугТовары.Сумма КАК Сумма
ИЗ
Документ.РеализацияТоваровУслуг.Товары КАК РеализацияТоваровУслугТовары
УПОРЯДОЧИТЬ ПО
РеализацияТоваровУслугТовары.Ссылка.Дата
ИТОГИ
СУММА(Количество),
СУММА(Сумма)
ПО
ОБЩИЕ,
Номенклатура

В результате выполнения запроса получим следующий результат:

дерево с общими итогами

В котором 1 уровень группировки – агрегирование всех нужных полей.

Упорядочивание

Оператор «УПОРЯДОЧИТЬ ПО» используется для сортировки результата запроса.

Сортировка для примитивных типов (строка, число, булево) происходит по обычным правилам. Для полей ссылочных типов сортировка происходит по внутреннему представлению ссылки (уникальный идентификатор), а не по коду или по представлению ссылки.

Пример:

ВЫБРАТЬ
Номенклатура.Наименование КАК Наименование
ИЗ
Справочник.Номенклатура КАК Номенклатура
УПОРЯДОЧИТЬ ПО
Наименование

Запрос выведет список наименований справочника номенклатуры, отсортированного по алфавиту.

Автоупорядочивание

Результат запроса без сортировки представляет собой хаотично представленный набор строк. Разработчики платформы 1С не гарантируют вывод строк в одинаковой последовательности при выполнении одинаковых запросов.

Если необходимо выводить записи таблицы в постоянном порядке необходимо использовать конструкцию «Автоупорядочивание».

Пример:

ВЫБРАТЬ
Номенклатура.Наименование КАК Наименование
ИЗ
Справочник.Номенклатура КАК Номенклатура
АВТОУПОРЯДОЧИВАНИЕ

Виртуальные таблицы

Виртуальные таблицы в 1С – это уникальная особенность языка запросов 1С, которой нет в других аналогичных синтаксисов. Виртуальная таблица – быстрый способ получения профильной информации из регистров.

Для каждого из типов регистров свой набор виртуальных таблиц, который может отличатся в зависимости от настроек регистра.

Регистр сведений:

  • Срез первых;
  • Срез последних.

Регистр накоплений:

  • Остатки;
  • Обороты;
  • Остатки и обороты.

Регистр бухгалтерии:

  • Движения с субконто;
  • Обороты;
  • Обороты Дт Кт;
  • Остатки;
  • Остатки и обороты
  • Субконто.

Регистр расчета:

  • База;
  • Данные графика;
  • Фактический период действия.

Для разработчика решения данные берутся из одной (виртуальной) таблицы, но на самом деле платформа 1С берёт из множества таблиц, преобразуя их в нужных вид.

Пример:

ВЫБРАТЬ
ТоварыНаСкладахОстаткиИОбороты.Номенклатура,
ТоварыНаСкладахОстаткиИОбороты.КоличествоНачальныйОстаток,
ТоварыНаСкладахОстаткиИОбороты.КоличествоОборот,
ТоварыНаСкладахОстаткиИОбороты.КоличествоПриход,
ТоварыНаСкладахОстаткиИОбороты.КоличествоРасход,
ТоварыНаСкладахОстаткиИОбороты.КоличествоКонечныйОстаток
ИЗ
РегистрНакопления.ТоварыНаСкладах.ОстаткиИОбороты КАК ТоварыНаСкладахОстаткиИОбороты

Такой запрос позволяет быстро получить большое количество данных.

Параметры виртуальных таблиц

Очень важный аспект работы с виртуальными таблицами – использование параметров. Параметры виртуальных таблиц – специализированные параметры для отбора и настройки.

Для таких таблиц считается не верным использования отбора в конструкции «ГДЕ». Помимо того, что запрос становится неоптимальным, возможно получение неверных данных.

Пример использования таких параметров:

РегистрНакопления.ТоварыНаСкладах.ОстаткиИОбороты(&НачалоПериода, &КонецПериода, Месяц, ДвиженияИГраницыПериода, Номенклатура = &НужнаяНоменклатура)

Алгоритм работы виртуальных таблиц

Например, наиболее используемая виртуальная таблица типа «Остатки» хранит данные в двух физических таблиц – остатков и движений.

При использование виртуальной таблицы система проделывает следующие манипуляции:

  1. Получаем ближайшее по дате и измерениям рассчитанное значение в таблице итогов;
  2. «Прибавляем» сумму из таблицы движения к сумме из таблицы итогов.


Такие простые действия могут существенно повысить производительность системы в целом.

Использование конструктора запросов

Конструктор запросов – инструмент, встроенный в систему 1С предприятие, существенно облегчающий разработку запросов к базе данных.

внешний вид консоли запросов 1С

Конструктор запроса имеет достаточно простой, интуитивно понятный интерфейс. Тем не менее рассмотрим применение конструктора запроса подробнее.

Запуск конструктора текста запроса производится контекстным меню (правой кнопкой мыши) в нужном месте программного кода.

Описание конструктора запроса 1С

Рассмотрим каждую вкладку конструктора подробнее. Исключение – вкладка Построитель, это тема для отдельного разговора.

Вкладка Таблицы и поля

внешний вид консоли запросов

На этой вкладке указывается источник данных и поля, которые необходимо выводить в отчет. По сути тут описываются конструкции ВЫБРАТЬ .. ИЗ.

В качестве источника может служить физическая таблица базы данных, виртуальная таблица регистров, временные таблицы, вложенные запросы и т.д.

В контекстном меню виртуальных таблиц можно задать параметры виртуально таблицы:

параметры виртуальной таблицы

Вкладка Связи

Вкладка служит для описания соединений нескольких таблиц, создает конструкции со словом СОЕДИНЕНИЕ.

связи в консоли запросов

Вкладка Группировка

На данной вкладке система позволяет группировать и суммировать нужные поля результата таблицы. Описывается использование конструкций СГРУППИРОВАТЬ ПО, СУММА, МИНИМУМ, СРЕДНЕЕ, МАКСИМУМ, КОЛИЧЕСТВО, КОЛИЧЕСТВО РАЗЛИЧНЫХ.

группировка в запросах 1С

Вкладка Условия

Отвечает за всё, что идёт в тексте запроса после конструкции ГДЕ, т.е за все условия, накладываемые на получаемые данные.

условие запросов

Вкладка Дополнительно

Вкладка Дополнительно изобилует всевозможными параметрами, которые являются очень важными. Рассмотрим каждое из свойств.

дополнительные функции

Группировка Выборка записей:

  • Первые N – параметр, возвращающий в запрос только N записей (оператор ПЕРВЫЕ )
  • Без повторяющихся – обеспечивает уникальность полученных записей (оператор РАЗЛИЧНЫЕ)
  • Разрешенные – позволяет выбирать только те записи, которые позволяет выбрать система с учетом настройки RLS (конструкция РАЗРЕШЕННЫЕ)

Группировка Тип запроса определяет, какой будет тип запроса – выборка данных, создание временных таблицы или же уничтожение временной таблицы.

Ниже существует флаг, Блокировать полученные данные для последующего изменения. Он позволяет включить возможность установки блокировки данных, которая позволяет обеспечить сохранность данных от момента их чтения до изменения (актуально только для Автоматического режима блокировок, конструкция ДЛЯ ИЗМЕНЕНИЯ).

Вкладка Объединения/Псевдонимы

объединения и псевдонимы

На этой вкладке конструктора запросов можно устанавливается возможность объединение разных таблиц и псевдонимы(конструкция КАК). В левой части указываются таблицы, если установить флаги напротив таблицы – будет использоваться конструкции ОБЪЕДИНИТЬ, иначе – ОБЪЕДИНИТЬ ВСЕ (отличия двух способов тут). В правой части указываются соответствия полей в разных таблицах, если соответствие не указано запрос будет возвращать NULL.

Вкладка Порядок

порядок в запросе

Здесь указывается порядок сортировки значений (УПОРЯДОЧИТЬ ПО) – по убыванию (УБЫВ) или возрастанию(ВОЗР).

Так же есть интересный флаг – Автоупорядочивание (в запросе – АВТОУПОРЯДОЧИВАНИЕ). По умолчанию, система 1С выводит данные в “хаотичном” порядке. Если установить этот флаг, система будет сортировать данные по внутренним данным.

Вкладка Пакет запросов

пакет запросов

На вкладке конструктора запросов можно создавать новые пакеты запросов, а также использовать её в роли навигации. В тексте запроса пакеты разделяются символом “;”(точка запятая).

Кнопка “Запрос” в конструкторе запросов

В левом-нижнем углу конструктора запроса есть кнопка Запрос, с помощью которого можно в любой момент просмотреть текст запроса:

В данном окне можно внести коррективы в запрос и выполнить его.

текст запроса

Использование консоли запросов

Консоль запросов – простой и удобный способ для отладки сложных запросов и быстрого получения информации. В этой статье я постараюсь описать как пользоваться консолью запросов и дам ссылку для скачивания консоли запросов.

внешний вид

Рассмотрим этот инструмент подробнее.

Скачать консоль запросов 1С

Первым делом, что бы начать работу с консолью запросов – её нужно откуда-то скачать. Обработки обычно делятся на два вида – на управляемых формах и обычных (или, иногда, их называют на 8.1 и на 8.2/8.3).

Я постарался объединить эти два вида в одной обработке – в нужном режиме работы открывается нужная форма (в управляемом режиме консоль работает только в толстом режиме).

Получить обработку можно по ссылке: Скачать универсальную консоль запросов 1С

Авторство обработок не наше, мы лишь объединили 2 наиболее удачные, на наш взгляд, консоли.

Описание консоли запросов 1С

Начнем рассмотрение консоли запросов с описания главной панели обработки:

запрос в консоле

В шапке консоли запросов можно увидеть время выполнения последнего запроса с точностью до миллисекунды, это позволяет сравнивать разные конструкции по производительности.

Первая группа кнопок в командной панели отвечает за сохранение текущих запросов во внешнем файле. Это очень удобно, вы всегда сможете вернутся к написанию сложного запроса. Или же, например, хранить список типичных примеров тех или иных конструкций.

Слева, в поле “Запрос” можно создавать новые запросы и сохранять их в древовидной структуре. Вторая группа кнопок как раз отвечает за управление списком запросов. С помощью неё можно создать, скопировать, удалить, переместить запрос.




Далее идут кнопки, отвечающие за инициализацию запроса:

выполнение запроса

  • Выполнить запрос – простое выполнение и получение результата
  • Выполнить пакет – позволяет просмотреть все промежуточные запросы в пакете запросов
  • Просмотр временных таблиц – позволяет увидеть результат, которые возвращают временные запросы в таблице

Параметры запроса:

внешний вид параметров запроса

Позволяют установить текущие параметры для запроса.

В окне параметров запроса интересно следующее:

  • Кнопка Получить из запроса автоматически находит все параметры в запросе, для удобства разработчика.
  • Флаг Единые параметры для всех запросов – при установке его обработка не очищает параметры при переходе от запроса к запросу в общем списке запросов.

Задать параметр списком значений очень просто, достаточно при выборе значения параметра нажат на кнопку очистки значения (крестик), система предложит выбрать тип данных, где надо выбрать “Список значения”:

тип параметров

Так же в верхней панели очень есть кнопка вызова настроек консоли запросов:

настройки консоли

Где можно указать параметры автосохранения запросов и параметры выполнения запроса.

В поле запроса консоли заносится текст запроса. Сделать это можно простым набором теста запроса или же вызовом специального инструмента – конструктора запросов.

Конструктор запроса 1С 8 вызывается из контекстного меню (правая кнопка мыши) при нажатии на поле ввода:

контекстное меню

Так же, в этом меню есть такие полезные  функции как очистка или добавление в запрос символов переноса строки (“|”) или же получения кода запроса вот в таком удобном виде:

Запрос = Новый Запрос;
Запрос.Текст = ”
|ВЫБРАТЬ
| Валюты.Ссылка
|ИЗ
| Справочник.Валюты КАК Валюты”;
РезультатЗапроса = Запрос.Выполнить();

В нижнем поле консоли запросов отображается поле результата запроса, ради чего и создана эта обработка:

режим отображения результата запроса

Так же, консоль запросов кроме списка умеет отображать данные в виде дерева, для запросов, содержащих итоги.

Оптимизация запросов

Один из важнейших пунктов в повышении производительности работы 1С предприятия 8.3 –  является оптимизация запросов.  Этот пункт так же очень важен при сдаче аттестации 1С- Эксперт по технологическим вопросам. Ниже пойдет речь о типичных причинах не оптимальной работы запросов и способах из оптимизации.

Отборы в виртуальной таблице с помощью конструкции ГДЕ

Накладывать фильтры на реквизиты виртуальной таблицы необходимо только через параметры ВТ. Не в коем случае для отбора в виртуальной таблице нельзя использовать конструкцию ГДЕ, это грубейшая ошибка с точки зрения оптимизации. В случае с отбором с помощью ГДЕ по факту система получит ВСЕ записи и только потом отберет нужные записи.

ПРАВИЛЬНО:

ВЫБРАТЬ
ВзаиморасчетыСДепонентамиОрганизацийОстатки.СуммаОстаток
ИЗ
РегистрНакопления.ВзаиморасчетыСДепонентамиОрганизаций.Остатки(
,
Организация = &Организация
И Физлицо = &Физлицо) КАК ВзаиморасчетыСДепонентамиОрганизацийОстатки

НЕПРАВИЛЬНО:

ВЫБРАТЬ
ВзаиморасчетыСДепонентамиОрганизацийОстатки.СуммаОстаток
ИЗ
РегистрНакопления.ВзаиморасчетыСДепонентамиОрганизаций.Остатки(, ) КАК ВзаиморасчетыСДепонентамиОрганизацийОстатки
ГДЕ
ВзаиморасчетыСДепонентамиОрганизацийОстатки.Организация = &Организация
И ВзаиморасчетыСДепонентамиОрганизацийОстатки.Физлицо = &Физлицо

Получение значения поля составного типа через точку

При получении данных составного типа в запросе через точку, система соединяет левым соединением ровно столько таблиц, сколько типов возможно в поле составного типа.

Например, крайне не желательно для оптимизации обращаться к полю записи регистра – регистратор. Регистратор имеет составной тип данных, среди которых все возможные типы документов, которые могут писать данные в регистр.

НЕПРАВИЛЬНО:

ВЫБРАТЬ
НаборЗаписей.Регистратор.Дата,
НаборЗаписей.Количество
ИЗ
РегистрНакопления.ТоварыOрганизаций КАК НаборЗаписей

Т.е по факту, вот такой запрос будет обращаться не к одной таблице, а к 22 таблицам базы данных ( у этого регистра 21 тип регистратора).

1С рекомендует экспертам в таком случае для оптимизации пожертвовать размером хранимых данных в пользу производительности или универсальностью кода ради производительности:

ПРАВИЛЬНО:

ВЫБРАТЬ
ВЫБОР
КОГДА ТоварыОрг.Регистратор ССЫЛКА Документ.РеализацияТоваровУслуг
ТОГДА ВЫРАЗИТЬ(ТоварыОрг.Регистратор КАК Документ.РеализацияТоваровУслуг).Дата
КОГДА ТоварыОрг.Регистратор ССЫЛКА Документ.ПоступлениеТоваровУслуг
ТОГДА ВЫРАЗИТЬ(ТоварыОрг.Регистратор КАК Документ.ПоступлениеТоваровУслуг).Дата
КОНЕЦ КАК Дата,
ТоварыОрг.Количество
ИЗ
РегистрНакопления.ТоварыОрганизаций КАК ТоварыОрг

Либо, второй вариант – добавление такой информации в реквизит, например, в нашем случае – добавление даты.

ПРАВИЛЬНО:

ВЫБРАТЬ
ТоварыОрганизаций.Дата,
ТоварыОрганизаций.Количество
ИЗ
РегистрНакопления.ТоварыОрганизаций КАК ТоварыОрганизаций

Подзапросы в условии соединения

Для оптимизации недопустимо использовать подзапросы в условиях соединения, это существенно замедляет работу запроса. Желательно в таких случаях использовать ВТ. Для соединения нужно использовать только объекты метаданных и ВТ, предварительно проиндексировав их по полям соединения.

НЕПРАВИЛЬНО:

ВЫБРАТЬ …
ИЗ Документ.РеализацияТоваровУслуг
ЛЕВОЕ СОЕДИНЕНИЕ (
ВЫБРАТЬ ИЗ РегистрСведений.Лимиты
ГДЕ …
СГРУППИРОВАТЬ ПО …
) ПО …

ПРАВИЛЬНО:

ВЫБРАТЬ …
ПОМЕСТИТЬ Лимиты
ИЗ РегистрСведений.Лимиты
ГДЕ …
СГРУППИРОВАТЬ ПО …
ИНДЕКСИРОВАТЬ ПО …;

ВЫБРАТЬ …
ИЗ Документ.РеализацияТоваровУслуг
ЛЕВОЕ СОЕДИНЕНИЕ Лимиты
ПО …;

Соединение записей с виртуальными таблицами

Бывает ситуации, когда при соединении виртуальной таблицы с другими система работает не оптимально. В таком случае для оптимизации работы запроса можно попробовать поместить виртуальную таблицу во временную, не забыв проиндексировать соединяемые поля в запросе временной таблицы. Связано это с тем, что ВТ часто содержатся в нескольких физических таблицах СУБД, в итоге для их выборки составляется подзапрос и проблема получается аналогичной предыдущему пункту.

Использование отборов по не индексируемым полям

Одна из самых распространенных ошибок при составления запросов – использование условий по не индексируемым полям, это противоречит правилам оптимизации запросов. СУБД не может выполнить запрос оптимально, если в запросе накладывается отбор по не индексируемым полям. Если же берется временная таблица – так же необходимо индексировать поля соединения.

Обязательно, для каждого условия должен существовать подходящий индекс. Подходящим является индекс,удовлетворяющий следующим требованиям:

  1.  Индекс содержит все поля перечисленные в условии;
  2.  Эти поля находятся в самом начале индекса;
  3.  Эти отборы идут подряд, то есть между ними не «вклиниваются» значения не участвующие в условии запроса;

Если СУБД не подобран правильные индексы,  то будет просканирована таблица полностью – это очень негативно скажется на производительности и может привести к продолжительной блокировки всего набора записей.

Использование логического ИЛИ в условиях

Настоятельно не рекомендуется злоупотреблять в условиях запросов конструкцией “ИЛИ”.

Вот и всё, в данной статье были освещены основы аспекты оптимизации запросов, которые должен знать каждый эксперт 1С.

Очень полезный бесплатный видеокурс по разработке и оптимизации запросов, категорически рекомендую новичкам и не только!

Другие статьи по 1С:

P.S. Наша компания предоставляет услуги по настройке, доработке и комплексному внедрению 1С. Закажите бесплатный расчет стоимости вашей задачи на странице Услуги 1С или по телефону +7 (499) 350 29 00.

Остались вопросы?

Задайте ВОПРОС на нашем форуме 1С! ››

СПРОСИТЕ в комментариях!

Комментариев: 12 на “Запросы 1С 8 от А до Я
  1. Все неплохо описано, но много ошибок. Исправьте.

    Ответить

    • Спасибо, быстро выложили. Займемся 🙂

      Ответить

  2. «Настоятельно не рекомендуется злоупотреблять в условиях запросов конструкцией “ИЛИ”.»

    Можно более подробно, почему настоятельно не рекомендуется?

    Ответить

    • Это приведет к неоптимальности запроса.

      Дело в том, что если у вас стоит условие вида:

      «ГДЕ Организация = &Организация И ( Контрагент = &Контрагент1 ИЛИ Контрагент = &Контрагент2)»

      Платформа чаще всего не сможет корректно обработать поиск по индексу для таких конструкций. Вполне возможно полное сканирование таблицы, что может привести к избыточным блокировкам.

      Обойди это можно созданием и объединением двух (и более) текстов запросов, где условия разбиты на два.

      Например.

      Условие первого запроса:
      «ГДЕ Организация = &Организация И Контрагент = &Контрагент1»
      Условие второго запроса:
      «ГДЕ Организация = &Организация И Контрагент = &Контрагент2»

      Ответить

      • Это все конечно так, но на практике я не встречал в типовых отчетах разбивки в на несколько запросов вместо «ИЛИ»

        Ответить

      • Не проще ли использовать «В»?
        Контрагент в (&МассивИзКонтр1иКонтр2)

        Ответить

  3. Проще написать, но не оптимально

    Ответить

  4. Как можно объединить 2 таблицы, чтобы наложить потом на них условие?

    Вот в таком формате:
    (Таблица А
    Объединить все
    Таблица Б)
    Внутреннее соединение
    Таблица Цэ

    ?

    Ответить

  5. Поместите в во временную таблицу и наложите любое условие.

    Ответить

  6. Здравствуйте! Я специалист в области финансов, пользователь 1с8. Начал осваивать 1с на уровне разработчика (есть производственная необходимость и самому очень интересно, появилось новое хобби). Начал с изучения литературы (Радченко), видео курсов (Чистов) и собственно с исследования имеющейся на предприятии конфигурации. Появился ряд глупых вопросов, которые для себя пометил, но пока в полной мере не прояснил (занимаюсь меньше месяца). Буду благодарен за ответы или ссылки на информацию, которая поможет разобраться.

    1.Архитектура: Тонкий клиент, Толстый клиент (1с Платформа –> 1с Конфигурация –> СУБД (Какая?) –> Сервер –> Компьютеры пользователей). Функции каждого компонента, как связан каждый из них с другими компонентами?

    2.Как происходит доработка конфигурации разработчиком, порядок?

    3.Процесс постановки задачи разработчику. Есть ли стандартизированный подход?

    4.В объектах Документ программный код хранится в Модуле объекта. В объекте Отчет – в конструкторе отчета. Это один и тот же язык запросов 1с? Где находится программный код других объектов? (например, регистров накоплений, справочников и т.д.)

    5.Такие категории, как Язык программирования 1с и Язык запросов 1с, это одно и то же? Если нет, чем отличаются и для чего используются каждый из них?

    6.Какая разница между такими категориями как Функция, Конструкция и Процедура?

    Ответить

    • Добрый день, Роман!

      1.Я бы расписал архитектуру проще:
      Клиентское приложение (ввод и вывод информации пользователю);
      Сервер 1С (интропретирует запрос от пользователя из «формата 1С» в «формат сервера СУБД»
      Сервер СУБД — одна из популярных IBM DB2, MS SQL Server, PostgreSQL или встроенная файловая версия в платформу 1С (выполняет всю работу — чтение и запись данных)

      2. Всегда по разному. Есть общее правило — если конфигурация типовая, стараться максимально избегать правки типового кода. Нужно стараться не влезать в существующий код, а делать доработки «сбоку» (простой пример: если нужно изменить проводки документа, лучше это сделать не в модуле «ОбработкаПроведения», я сделать подписку на событие и изменить проводки там). Это сократить трудозатраты на поддержку и обновление в дальнейшем.

      3. У каждой компании свои наработки. Обычно это 3 пункта: зачем нужна разработка, как её реализовать, как проверить. Зависит от уровня знаний постановщика задач.

      4. Почти у каждого объекта есть модуль объекта, в том числе отчетах. В этих модулях есть набор предопределенных процедура, которые для удобства использует разработчик. В целом — никакого регламента в этом нет.

      5. Язык программирования — общее название встроенного языка 1С. Запросы 1С — это «подраздел» языка программирования 1С, который позволяет удобнее работать с получением данных из базы.

      6.
      Функция — возвращает какое либо значение (например: КурсВалюты = ПолучитьКурсВалютыНаДату(Дата))
      Процедура — просто выполняет какую либо функцию (например: ВыполнитьДвиженияПоРегистру()))
      Конструкция — речевой оборот, под этим словом может иметься ввиду что угодно, но обычно это кусок кода.

      Ответить

      • Спасибо, Кирилл! Резкость немного навелась)

        Ответить

Добавить комментарий:

Ваш e-mail не будет опубликован. Обязательные поля помечены *


*