Работа с двоичными данными в 1С 8.3 и 8.2

Важное замечание в начале. Основной режим работы 1С в этой статье предполагается 1С 8.3.7 в режиме тонкого клиента без модальных вызовов — самый современный на настоящий момент, на который вскоре должны быть переведены все конфигурации. Также постараюсь описать особенности работы в Веб-Клиенте.

Что такое двоичные данные и как с ними можно работать в 1С 8

Двоичные данные (или бинарные) — это файл данных произвольного формата.

Платформа 1С (8.3 и 8.2) в общем случае понятия не имеет, что это. Предполагается, что программист или пользователь знает, какие именно это данные и как их применять. Тем не менее, если в двоичные данные загружен графический файл, формат которого понимает объект типа «Картинка», то при инициализации картинки такими двоичными данными картинка будет нормально показана, а её свойство «Формат» примет правильное значение.

Платформа 1С при работе с двоичными данными может:

• Хранить в базе данных в реквизитах типа «ХранилищеЗначения», в справочниках, документах, регистрах сведений.
• Читать их из файла и записывать в файл.
• Передавать их между сервером и клиентом через временное хранилище.
• Инициализировать ими объект типа «Картинка».
• Закодировать и раскодировать в/из строковое представление Base64.
• Хранить в объектах конфигурации в качестве Макета.
• Читать двоичные данные из сети при помощи объектов типа «HTTPСоединение» (объект «HTTPОтвет» можно получить в том числе в виде двоичных данных), «ПочтовоеВложение», «ИнтернетПочтовоеВложение».
• Зашифровать, расшифровать, подписать и проверить подпись средствами криптографии.
• Вычислить хеш-функцию с помощью объекта типа «ХешированиеДанных»

Возможно, я еще что-то упустил, однако интуитивно ясно, что практически все, что надо для работы с двоичными данными в 1С, у нас есть. Рассмотрим теперь по порядку несколько конкретных примеров работы с двоичными данными на платформе 1С 8.3.

Чтение и запись двоичных данных в файл

Основной тип объектов двоичных данных платформы 1С так и называется: «ДвоичныеДанные». Вот что говорит о нем «Синтаксис-помощник»:

Значение содержит двоичные данные, которые считываются из файла. Значение может быть сохранено в ХранилищеЗначения. Хранимые данные могут быть записаны в файл.

Доступность: Тонкий клиент, веб-клиент, сервер, толстый клиент, внешнее соединение, мобильное приложение(клиент), мобильное приложение(сервер).

Сериализуется. Данный объект может быть сериализован в/из XML. Может использоваться в реквизитах управляемой формы.

Чтение двоичных данных из файла

Тип «Двоичные данные» имеет единственный конструктор:

дд = Новый ДвоичныеДанные(имяФайла);

имяФайла — обязательный аргумент.

В итоге получаем программный объект двоичных данных, прочитанный из файла.

Запись двоичных данных в файл

дд.Записать(имяФайла);

Определение размера двоичных данных в байтах

квоБайт = дд.Размер();

Сохранение двоичных данных в реквизит объекта

Рассмотрим сразу запись двоичных данных из файла на клиенте в реквизит объекта базы данных типа ХранилищеЗначения. Причем напишем такой код, который сработает и на веб-клиенте, а также будет лишен модальных вызовов, то есть таких вызовов, которые ожидают действия пользователя и останавливают при этом исполнение программы. Теперь платформа 1С 8.3 требует разрабатывать асинхронные программы.

Выглядит это примерно так: создается обработчик оповещения о выполнении некоторой длительной процедуры, затем запускается процедура «НачатьХХХ()», в которую, кроме понятных аргументов, передается еще и описание обработчика ее завершения. Наша программа спокойно работает далее, а по завершении запущенной процедуры вызывается наш обработчик завершения.

Предположим, у нас на форме есть реквизит типа «СправочникСсылка.Картинки». Справочник «Картинки» имеет реквизит «ДанныеКартинки» типа ХранилищеЗначения.

Создадим команду формы «ЗагрузитьКартинкуИзФайла».

Создадим обработчик команды, выделив команду в списке команд формы и нажав на кнопку с увеличительным стеклом в поле «Действие» панели свойств:

Поскольку все необходимые параметры для записи картинки мы можем передать изнутри клиентской части обработчика, нам нет нужды создавать контекстную серверную процедуру на сервере. Выберем «Создать на клиенте и процедуру на сервере без контекста»:

Вначале напишем наши обработчики команды в старом, «модальном» или «синхронном» стиле:

&НаСервереБезКонтекста

Процедура ЗагрузитьКартинкуИзФайлаНаСервере(стрАдрес, спрКартинка)

объКартинка = спрКартинка.ПолучитьОбъект();

объКартинка.Картинка = Новый ХранилищеЗначения(ПолучитьИзВременногоХранилища(стрАдрес));

объКартинка.Записать();

КонецПроцедуры

&НаКлиенте

Процедура ЗагрузитьКартинкуИзФайла(Команда)

адресДанных = "";

Если ЗначениеЗаполнено(Картинка) Тогда

Если ПоместитьФайл(адресДанных, ИмяФайлаКартинки, ИмяФайлаКартинки, Истина, УникальныйИдентификатор) Тогда

ЗагрузитьКартинкуИзФайлаНаСервере(адресДанных, Картинка);

КонецЕсли; // ПоместитьФайл((Новый ДвоичныеДанные(ИмяФайлаКартинки))

КонецЕсли; // ЗначениеЗаполнено(Картинка)

КонецПроцедуры

В моей небольшой тестовой конфигурации этот код отлично сработал в режиме тонкого клиента. Теперь преобразуем модальный вызов «ПоместитьФайл» в асинхронный, он же немодальный. В меню конфигуратора запустим команду меню «Текст >Рефакторинг >Нерекомендуемые синхронные вызовы >Преобразовать вызовы модуля». Нам в ответ сообщат, что «Не рекомендуемых синхронных вызовов преобразовано: 1».

Для компактности я удалил все пустые строки, и вот что получилось вместо клиентской части нашего обработчика:

&НаКлиенте

Процедура ЗагрузитьКартинкуИзФайла(Команда)

адресДанных = "";

Если ЗначениеЗаполнено(Картинка) Тогда

НачатьПомещениеФайла(Новый ОписаниеОповещения("ЗагрузитьКартинкуИзФайлаЗавершение", ЭтаФорма, Новый Структура("адресДанных", адресДанных)), адресДанных, ИмяФайлаКартинки,, Истина, УникальныйИдентификатор);

КонецЕсли; // ЗначениеЗаполнено(Картинка)

КонецПроцедуры

&НаКлиенте

Процедура ЗагрузитьКартинкуИзФайлаЗавершение(Результат, Адрес, ИмяФайлаКартинки, ДополнительныеПараметры) Экспорт

адресДанных = ДополнительныеПараметры.адресДанных;

Если Результат Тогда

ЗагрузитьКартинкуИзФайлаНаСервере(адресДанных, Картинка);

КонецЕсли; // ПоместитьФайл((Новый ДвоичныеДанные(ИмяФайлаКартинки))

КонецПроцедуры

Готово! Мы кошерно асинхронно записали картинку из файла на клиенте в реквизит объекта базы данных, в нашем случае — элемента справочника.

Чтение двоичных данных из объекта БД

Для чего нам надо читать двоичные данные из объекта БД? Наверное, три самых частых случая таковы:

1. Внедрить картинку в табличный документ, например, отчет. Табличный документ (отчет) часто формируется на стороне сервера, поэтому нам нет нужды гонять картинки через временное хранилище. Мы просто получаем значение из реквизита типа «хранилище значения», инициализируем им объект типа «Картинка» и помещаем эту картинку в табличный документ. А клиентская сторона приложения отображает уже сформированный табличный документ.
2. Отобразить на форме некоторую картинку. Нам надо передать двоичные данные на сторону клиента и загрузить их в реквизит формы при открытии формы. Ну и желательно обновлять картинку по некоторым событиям.
3. Сохранить двоичный файл на стороне клиента. Здесь надо получить данные с сервера по некоторой команде и просто сохранить их в файл на клиенте.

Пример 1. Вставить картинки в  макет (табличный документ).

Допустим, у нас есть база данных со справочником «Картинки», у элементов которых есть реквизит «Картинка» типа ХранилищеЗначения, содержащий данные картинки.

Создадим новую внешнюю обработку, ее основную форму.

На форме создадим 3 реквизита «СпрКартинка1», «СпрКартинка2», «СпрКартинка3» типа «СправочникСсылка.Картинки» и реквизит «ТабДок» типа «ТабличныйДокумент». Перетащим мышкой эти реквизиты в список элементов формы, чтобы на ней образовались соответствующие поля.

Добавим команду формы «НапихатьКартинок» и создадим ее обработчик. На сей раз выберем «Создать на Клиенте и процедуру на сервере», чтобы не передавать много параметров в процедуру без контекста. Напишем такие обработчики:

&НаСервере

Процедура НапихатьКартинокНаСервере()

Для сч = 1 По 3 Цикл

картинка = Новый Картинка(ЭтаФорма["СпрКартинка" + сч].Картинка.Получить());

ТабДок.Область(4-сч, сч, 4-сч, сч).Картинка = картинка;

КонецЦикла; // Для сч = 1 По 3

КонецПроцедуры

&НаКлиенте

Процедура НапихатьКартинок(Команда)

НапихатьКартинокНаСервере();

КонецПроцедуры

И получим примерно такой результат:

Пример 2. Показать картинку из базы данных на форме.

Для демонстрации воспользуемся первой обработкой, где мы записывали файл в БД. Теперь покажем на форме картинку, которая записана в реквизите «Картинка» выбранного на форме элемента справочника «Картинки».

Во-первых, добавим на форму поле, связанное с реквизитом «АдресДанныхКартинки». Например, перетащим мышкой этот реквизит в список элементов формы. Выберем и установим значение свойства «Вид» этого поля в «Поле картинки».

Во-вторых, напишем такую серверную процедуру:

&НаСервере
Процедура ОбновитьКартинкуНаСервере()
АдресДанныхКартинки = ПоместитьВоВременноеХранилище(Картинка.Картинка.Получить());
КонецПроцедуры // ОбновитьКартинку

И станем вызывать эту процедуру, например, из обработчика события «При изменении» поля «Картинка»:

&НаКлиенте
Процедура КартинкаПриИзменении(Элемент)
ОбновитьКартинкуНаСервере();
КонецПроцедуры

Проверяем…

Работает!

Сохранение двоичных данных в файл на клиенте

Думаю, с сохранением двоичных данных из базы данных в файл у Вас проблем не возникнет. По крайней мере, если Вы работаете не в веб-клиенте. Читаем, помещаем во временное хранилище на сервере, затем записываем в файл на клиенте.

Кодирование двоичных данных в формат Base64 и обратно

Тут все очень просто. Платформа имеет две глобальные функции, доступные везде:

• Base64Строка(<Значение>)
• Base64Значение(<Строка>)

Первая получает в качестве аргумента объект типа «ДвоичныеДанные», а возвращает его текстовое представление в кодировке base64, а вторая, наоборот, из текста в формате base64 возвращает объект типа «ДвоичныеДанные».

Не очень, правда, представляю, зачем нам это может понадобиться. Во всех встроенных типах объектов вроде ПочтовоеВложение или объектов для работы с XML необходимые преобразования платформа делает сама. Разве что нам потребуется работать с какими-то нестандартными форматами файлов для обмена с внешними системами…

Итого

На самых простых примерах мы увидели все основные принципы и методы работы с двоичными данными в 1С 8.3. Также коснулись актуальной сейчас темы устранения синхронных вызовов. Остальные возможности работы с двоичными данными Вы без труда реализуете по аналогии с рассмотренными здесь.

Спасибо за внимание. Желаю всем вершин профессионализма и глубин познаний. А главное — чтобы это приносило счастье в жизнь Вашу и окружающих.

Если Вы начинаете изучать 1С программирование, рекомендуем наш бесплатный курс (не забудьте подписаться на YouTube — регулярно выходят новые видео):